;z80
;zx-spectrum
;assembler

; сами проги просмотра (part2)

        MAIN "LView04",9

FN3_SHW XOR A
        CALL IMGBANK
        LD HL,#C000
        LD DE,#C001
        LD BC,#7FF
        LD (HL),L
        LDIR 
        LD HL,#C100
        LD B,3
        CALL FLOAD
        LD A,#37
        JR FNA_SHW

FN8_SHW CALL LOADALL
        XOR A
        CALL IMGBANK
        LD A,#A7
FNA_SHW LD (fnt_A1),A
        LD HL,#C000
        LD DE,#C800
f8_1    LD C,8
f8_2    LD A,(HL)
        LD (DE),A
        INC HL
        INC D
        DEC C
        JR NZ,f8_2
        LD D,#C8
        INC E
        JR NZ,f8_1
        LD HL,#4085
        LD BC,#9410
        LD A,4
        CALL WINDOW
        LD HL,#43A5
        LD DE,#7FFE
        LD A,#FF
        CALL line

        LD HL,#58C6
        LD B,16
f8_3    LD C,16
f8_4    LD (HL),7
        INC L
        DEC C
        JR NZ,f8_4
        LD A,16
        ADD A,L
        LD L,A
        ADC A,H
        SUB L
        LD H,A
        DJNZ f8_3

see_BIT LD HL,#C800
        CALL OUTFONT
        LD HL,fnt_bit
        CALL FNT_STR
seeb_1  CALL NOKEY
        CALL WAITKEY
fnt_A1  AND A
        JR C,seeb_1A
        CP "2"
        JR Z,see_SCR
seeb_1A CP 32
        JR Z,see_EX
        CP 13
        JR NZ,seeb_1
see_EX  JP NOKEY

see_SCR LD HL,#C000
        CALL OUTFONT
        LD HL,fnt_scr
        CALL FNT_STR
seeb_2  CALL NOKEY
        CALL WAITKEY
        CP "1"
        JR Z,see_BIT
        CP 13
        JR Z,see_EX
        CP 32
        JR Z,see_EX
        JR seeb_2

FNT_STR LD A,#0F
        LD (scrmask+1),A
        CPL 
        LD (fntmask+1),A
        LD A,6
        LD (color+1),A
        JP STRING

fnt_bit DB 1,#86,#40
        DB " растр  ",0
fnt_scr DB 1,#86,#40
        DB " экран  ",0

OUTFONT LD DE,#40C6
        LD B,16
ofnt_1  PUSH DE
        LD C,16
ofnt_2  PUSH DE
        PUSH HL
        LD A,8
ofnt_3  EXA 
        LD A,(HL)
        LD (DE),A
        INC H
        INC D
        EXA 
        DEC A
        JR NZ,ofnt_3
        POP HL
        POP DE
        INC L
        INC E
        DEC C
        JR NZ,ofnt_2
        POP DE
        LD A,E
        ADD A,32
        LD E,A
        JR NC,ofnt_4
        LD A,D
        ADD A,8
        LD D,A
ofnt_4  DJNZ ofnt_1
        RET